# $Id: PKGBUILD 108702 2014-04-01 17:09:32Z speps $
# Maintainer: speps <speps at aur dot archlinux dot org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: dorphell <dorphell@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Aditya Som <icarious@hacari.org>"

_pkgname=sylpheed
pkgname=sylpheed-nonprism
pkgver=3.4.0
pkgrel=1
pkgdesc="Lightweight and user-friendly e-mail client, without Gmail support"
arch=('i686' 'x86_64')
url="http://sylpheed.sraoss.jp/en/"
license=('GPL')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('compface' 'gpgme' 'gtkspell' 'desktop-file-utils')
makedepends=('openssl')
install="$_pkgname.install"
source=("http://sylpheed.sraoss.jp/$_pkgname/v${pkgver%.*}/$_pkgname-$pkgver.tar.bz2"
        'nonprism.patch')
md5sums=('6cef3bb0ef2de6456dc1710f58e4db1f'
         'e1bddc14962e607cdb899ec082660639')

prepare() {
  cd $_pkgname-$pkgver

  # Remove Gmail support
  patch -Np1 -i "$srcdir/nonprism.patch"
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr \
              --enable-ldap
  make

  # Build Attachment-Tool Plug-in
  cd plugin/attachment_tool && make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir/" install

  # Install Attachment-Tool Plug-in
  cd plugin/attachment_tool
  make DESTDIR="$pkgdir/" install-plugin
}