# $Id: PKGBUILD 209631 2017-02-01 11:02:26Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Joeny Ang <ang(dot)joeny(at)gmail(dot)com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=shotwell
epoch=1
pkgver=0.24.5
_basever=${pkgver%.*}
pkgrel=1.nonprism1
pkgdesc="A digital photo organizer designed for the GNOME desktop environment, without support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64' 'armv7h')
url="http://yorba.org/shotwell/"
license=('LGPL2.1')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('libgee' 'webkit2gtk' 'libgexiv2' 'libraw' 'rest'
	 'desktop-file-utils' 'dconf' 'hicolor-icon-theme' 'json-glib'
	 'gst-plugins-base' 'libgphoto2' 'libgudev')
makedepends=('intltool' 'vala>=0.17.2' 'gnome-doc-utils' 'itstool')
# odd versions are unstable!
source=("https://download.gnome.org/sources/shotwell/${_basever}/shotwell-$pkgver.tar.xz"
        'nonprism.patch')
sha256sums=('4936c2c8c63b701ac0cf15b7bd6619ee3241a6d08b4187f2475348642ff9c1fd'
            '99647c08bb0b7a12575e2ae3b6d794d6b3e2a72059e905bae5e86575628475d0')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i ../nonprism.patch

  cd po
  sed -i '\|set_background_slideshow_dialog.glade|d' $(grep -rIl set_background_slideshow_dialog.glade)
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --libexec=/usr/lib \
	--disable-schemas-compile \
	--disable-desktop-update \
	--disable-icon-update \
        --disable-extra-plugins-install
  make -j1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}