# $Id: PKGBUILD 114629 2014-07-02 10:24:53Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Joeny Ang <ang(dot)joeny(at)gmail(dot)com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

_pkgname=shotwell
pkgname=shotwell-nonprism
pkgver=0.18.1
pkgrel=1
pkgdesc="A digital photo organizer designed for the GNOME desktop environment, without support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64')
url="http://yorba.org/shotwell/"
license=('LGPL2.1')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
depends=('libgee' 'webkitgtk' 'libgexiv2' 'libraw' 'rest'
	 'desktop-file-utils' 'dconf' 'hicolor-icon-theme' 'json-glib'
	 'gst-plugins-base' 'libgphoto2')
makedepends=('intltool' 'vala>=0.17.2' 'libunique3' 'gnome-doc-utils')
install=shotwell.install
source=("https://download.gnome.org/sources/shotwell/0.18/shotwell-$pkgver.tar.xz"
        'nonprism.patch')
md5sums=('361eeef67f5aaed36ec44b12cfd675b3'
         'b6c67e76af91be99852310e9c2be5ffa')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  patch -Np1 -i ${srcdir}/nonprism.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr --libexec=/usr/lib/shotwell \
	--disable-schemas-compile \
	--disable-desktop-update \
	--disable-icon-update \
        --disable-extra-plugins-install
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}