# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=kopete

pkgver=17.08.3
pkgrel=1.parabola2.nonprism1
arch=(i686 x86_64 armv7h)

pkgdesc="Instant Messenger, without nonfree Skype support and support for unsafe and dangerous for privacy protocols"
url="https://kde.org/applications/internet/kopete/"
license=(GPL LGPL FDL)

makedepends=(cmake automoc4 boost mediastreamer libgadu jsoncpp openssl-1.0)
depends=(kdebase-runtime libotr qimageblitz qca-qt4 qjson)
optdepends=('mediastreamer: jingle support')
conflicts=(kdenetwork-kopete)
replaces=(kdenetwork-kopete)

source=("https://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"{,.sig}
        kopete-mediastreamer2.14.patch
        kopete-pthread-link.patch
        kopete-no-kdepimlibs.patch
        libre-nonprism.patch)
sha256sums=('f86ccc1ca809c723d1baf2eed745f158337059263555f6fafa23ea200aacafec'
            'SKIP'
            'c34a268aaa058e563174581dbe37c15fed91e82326ec704d2a872463139865e0'
            'a7ebdd8dd4336b7ec085ef254bf18040f473b73379a8cd84569b28441a6c71df'
            'b9e7f0029dabe6a738114b11a093eb7d24aaf1e71b26d089901246e56cbeacf5'
            'c1824f31afbe37089508a7bc3ac29e5a5835e0aac6fd53d8097085cde1e3cf23')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build

  cd kopete-$pkgver

  # based on https://devel.trisquel.info/trisquel/package-helpers/blob/belenos/helpers/make-kopete
  sed -i 's/Skype protocol" ON/Skype protocol" OFF/g' protocols/CMakeLists.txt
  rm -rf protocols/skype
  sed 's/, Skype//' -i ./doc/index.docbook

  # Remove unsafe/dangerous services
  rm -rv protocols/oscar
  rm -rv protocols/yahoo
  rm -rv protocols/qq
  rm -rv protocols/groupwise
  rm -rv protocols/gadu
  rm -rv protocols/wlm
  rm -rv protocols/meanwhile
  patch -p1 -i "${srcdir}"/libre-nonprism.patch

  # Fix build with mediastreamer 2.14
  patch -p1 -i ../kopete-mediastreamer2.14.patch
  # Fix linking to pthread in libjingle-call
  patch -p1 -i ../kopete-pthread-link.patch
  # Remove kdepimlibs usage
  patch -p1 -i ../kopete-no-kdepimlibs.patch
}

build() {
  cd build

  cmake ../kopete-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_Libgadu=OFF \
    -DWITH_skype=OFF \
    -DWITH_oscar=OFF \
    -DWITH_yahoo=OFF \
    -DWITH_qq=OFF \
    -DWITH_groupwise=OFF \
    -DWITH_gadu=OFF \
    -DWITH_GOOGLETALK=OFF \
    -DWITH_wlm=OFF \
    -DWITH_WLM_MEDIASTREAMER=OFF \
    -DWITH_meanwhile=OFF \
    -DOPENSSL_INCLUDE_DIR=/usr/include/openssl-1.0 \
    -DOPENSSL_SSL_LIBRARY=/usr/lib/openssl-1.0/libssl.so \
    -DOPENSSL_CRYPTO_LIBRARY=/usr/lib/openssl-1.0/libcrypto.so
  make
}

package() {
  cd build

  make DESTDIR="$pkgdir" install
}