# $Id: PKGBUILD 211141 2014-04-17 06:54:31Z andrea $
# Maintainer: Ronald van Haren <ronald@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
_pkgname=kipi-plugins
pkgname=kipi-plugins-libre-nonprism
pkgver=3.5.0
pkgrel=4
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree jAlbum and SimpleViewer support and support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.digikam.org/"
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
makedepends=('kdepimlibs' 'libkexiv2' 'libkdcraw' 'libkipi' 'libksane' 'liblqr'
             'kdeedu-marble' 'opencv' 'boost' 'libgpod' 'qjson' 'hugin' 'libgphoto2'
             'cmake' 'automoc4' 'doxygen' 'lensfun' 'qt-gstreamer' 'imagemagick' 'eigen')
depends=('kdebase-runtime' 'kdepimlibs' 'libkdcraw' 'libkipi' 'libksane' 'libkexiv2')
optdepends=('libkgeomap: Geolocalize tool'
            'libmediawiki: MediaWiki Export plugin'
            'libgpod: iPodExport plugin'
            'opencv: Remove Red Eyes plugin'
            'imagemagick: Video SlideShow plugin'
            'qt-gstreamer: Video SlideShow plugin')
options=('staticlibs')
install=kipi-plugins.install
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2")
sha1sums=('9e44fcf219312cbcbbaee0cc9a7f460a01769224')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  sed -i '\|flashexport|d
          \|jalbumexport|d
          \|imageshackexport|d
          s| Facebook, and Imgur||
          \|QtKOAuth|d
          \|Imgur|d
          \|imgurexport|d
          \|LIBKVKONTAKTE|d
          \|vkontakte|d
          s| and YandexFotki||
          \|YandexFotki|d
          \|yandexfotki|d
          \|DlnaExport|d
          \|dlnaexport|d
          \|Facebook|d
          \|facebook|d
          \|flickrexport|d
          \|picasawebexport|d
         ' extra/kipi-plugins/CMakeLists.txt
  sed -i '\|m_actionExport| s|true|false|
         ' extra/kipi-plugins/smug/plugin_smug.cpp
  sed -i '\|Remote Flickr Export plugin|,+2 d
          \|flickrexport|d
         ' doc/kipi-plugins/index.docbook
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_tests=OFF \
    -DDIGIKAMSC_USE_PRIVATE_KDEGRAPHICS=OFF
  make
}

package() {
  cd build/extra/kipi-plugins
  make DESTDIR="${pkgdir}" install
}