# $Id: PKGBUILD 214668 2014-06-09 03:18:28Z svenstaro $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgbase=kdepim
pkgname=kdepim-kmail-nonprism
pkgver=4.13.2
pkgrel=1
arch=('i686' 'x86_64')
url='http://pim.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdepim')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-runtime-nonprism' 'libxss' 'pilot-link'
             'baloo' 'link-grammar')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.xz")
sha1sums=('ecc10cdec4fbe9a8b2c8179921403cf9b3aedac9')

build() {
	mkdir build
	cd build
	cmake ../${pkgbase}-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DKDE4_BUILD_TESTS=OFF \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DKDEPIM_BUILD_MOBILE=OFF
	make
}

package_kdepim-kmail-nonprism() {
	pkgdesc='Mail Client, without libkgapi support'
	depends=('kdepim-libkdepim' 'kde-agent')
	url="http://kde.org/applications/internet/kmail/"
	install='kdepim-kmail.install'
	conflicts=('kdepim-kmailcvt' 'kdepim-ksendemail' 'kdepim-libksieve'
	           'kdepim-mimelib' 'kdepim-plugins' 'kdepim-kmail')
	replaces=('kdepim-kmailcvt' 'kdepim-ksendemail' 'kdepim-libksieve'
	          'kdepim-mimelib' 'kdepim-plugins' 'kdepim-kmail')
	provides=("kdepim-kmail=$pkgver")
  for i in kmail kmailcvt agents/archivemailagent storageservicemanager\
    agents/mailfilteragent importwizard ksendemail libksieve messagelist \
    kontact/plugins/kmail headerthemeeditor mboximporter; do
    cd "${srcdir}"/build/${i}
    make DESTDIR="${pkgdir}" install
  done
}