# $Id: PKGBUILD 241398 2015-06-29 17:50:28Z arojas $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdenetwork-kopete
pkgver=15.04.3
pkgrel=1.parabola1.nonprism1
pkgdesc='Instant Messenger, without nonfree Skype support and support for unsafe and dangerous for privacy protocols'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdenetwork')
replaces=(${pkgname}-libre ${pkgname}-libre-nonprism)
conflicts=(${pkgname}-libre ${pkgname}-libre-nonprism)
depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr' 'qimageblitz' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-libkdepim' 'mediastreamer' 'kdepim-kleopatra')
optdepends=('mediastreamer: jingle support')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"
        'libre-nonprism.patch')
sha1sums=('1dddde0459361c47bcc7a27b88f8a53499cf73c5'
          'f0d7b727da1b5160f05952eec4df1bfbefab99cf')

prepare() {
  cd kopete-${pkgver}
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  # remove unsafe/dangerous services
  rm -rv protocols/oscar
  rm -rv protocols/yahoo
  rm -rv protocols/qq
  rm -rv protocols/groupwise
  rm -rv protocols/gadu
  rm -rv protocols/wlm
  rm -rv protocols/meanwhile
  patch -p1 -i "${srcdir}"/libre-nonprism.patch
  cd ..
  mkdir -p build
}

build() {
  cd build
  cmake ../kopete-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_Libgadu=OFF \
    -DWITH_skype=OFF \
    -DWITH_oscar=OFF \
    -DWITH_yahoo=OFF \
    -DWITH_qq=OFF \
    -DWITH_groupwise=OFF \
    -DWITH_gadu=OFF \
    -DWITH_GOOGLETALK=OFF \
    -DWITH_wlm=OFF \
    -DWITH_WLM_MEDIASTREAMER=OFF \
    -DWITH_meanwhile=OFF
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}