# $Id: PKGBUILD 288880 2017-02-13 13:39:34Z jgc $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor (Arch): Tobias Kieslich <tobias@justdreams.de>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=gthumb
pkgver=3.4.4.1
pkgrel=3.nonprism1
pkgdesc="Image browser and viewer for the GNOME Desktop, without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Apps/gthumb"
arch=(i686 x86_64)
license=(GPL)
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
         libsecret libsoup webkit2gtk json-glib)
makedepends=(intltool libchamplain exiv2 itstool brasero libraw liboauth docbook-xsl
             yelp-tools flex gnome-common git)
optdepends=('libraw: read RAW files'
            'exiv2: metadata support'
            'libchamplain: map viewer'
            'brasero: burn discs'
            'liboauth: web albums')
_commit=849e68f5ba606c25988a1e9e6669519734a7449a  # gthumb-3-4
source=("git+https://git.gnome.org/browse/gthumb#commit=$_commit"
        0001-Do-not-process-bitmap-thumbnails-with-invalid-color-.patch
        nonprism.patch)
sha256sums=('SKIP'
            '9cdffadd2b2c21904a997b4ab4ef311c18a59dfa6a3b236570af7f1465a36c60'
            'b1cd2463ab6475ce91a2b2e83dfcb1835ffaa9640c59d7bcfbe611163327fa45')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  # Fixup tags for pkgver()
  git tag -f 3.4.4.1 849e68f5ba606c25988a1e9e6669519734a7449a
  NOCONFIGURE=1 ./autogen.sh
  patch -Np1 -i ../0001-Do-not-process-bitmap-thumbnails-with-invalid-color-.patch
  patch -Np1 -i ../nonprism.patch
}

build() {
  cd $pkgname

  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --enable-libchamplain

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}