# $Id: PKGBUILD 287540 2017-01-26 20:52:06Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=gnome-weather
pkgver=3.20.2
pkgrel=2.nonprism1
pkgdesc="Access current weather conditions and forecasts, without geoclue2 support"
url="https://wiki.gnome.org/Apps/Weather"
arch=(any)
license=(GPL)
depends=(gtk3 gjs libgweather gnome-desktop)
makedepends=(intltool gobject-introspection autoconf-archive appstream-glib git)
groups=(gnome-extra)
_commit=dc0de147404ca887471990c54f6cd94afe27dcd2  # tags/3.20.2^0
source=("git+https://git.gnome.org/browse/gnome-weather#commit=$_commit"
        nonprism.patch)
sha256sums=('SKIP'
            '310d0d1b61e4d791abe6670418ae53d10595f0e7a772d3e73ab59a454385d8be')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -p1 -i $srcdir/nonprism.patch
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}