# $Id: PKGBUILD 208734 2014-03-25 23:34:47Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@parabola.nu>

_pkgname=gnome-online-accounts
pkgname=gnome-online-accounts-nonprism
pkgver=3.12.0
pkgrel=1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64 mips64el)
url="http://www.gnome.org"
license=('GPL')
depends=('webkitgtk' 'json-glib' 'libnotify' 'rest' 'hicolor-icon-theme' 'libsecret'
         'telepathy-glib' 'krb5' 'gcr')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl')
provides=("$_pkgname=$pkgver")
conflicts=$_pkgname
replaces=($_pkgname $pkgname-coherence)
install=$_pkgname.install
source=(http://ftp.gnome.org/pub/gnome/sources/$_pkgname/${pkgver:0:4}/$_pkgname-$pkgver.tar.xz)
sha256sums=('81d44afb3b993b7fb465d19b1b572db423bc7591e309f829d0639c802d7dfcc2')

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --libexecdir=/usr/lib/$_pkgname --disable-static \
    --disable-exchange --disable-facebook -disable-flickr \
    --disable-google --enable-imap-smtp --disable-kerberos \
    --enable-owncloud --enable-telepathy --disable-windows-live \
    --disable-twitter --disable-yahoo
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: