# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=gnome-online-accounts
pkgname=gnome-online-accounts-nonprism
pkgver=3.8.2
pkgrel=2.1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64 mips64el)
url="http://www.gnome.org"
license=('GPL')
depends=('webkitgtk3' 'json-glib' 'libnotify' 'rest' 'hicolor-icon-theme' 'libsecret')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl')
provides=("$_pkgname=$pkgver")
conflicts=$_pkgname
replaces=($_pkgname $pkgname-coherence)
options=(!libtool)
install=$_pkgname.install
source=(http://download.gnome.org/sources/$_pkgname/${pkgver:0:3}/$_pkgname-$pkgver.tar.xz
        imap-smtp.patch
        smtp-auth-plain.patch)
sha256sums=('12611a002043c8acc29e9800ec009e3e19736bdb6237d246e848d7c7909fe826'
            '2b413d1f401647bd143b7dc6dd4b6d6660ff47ef9a11ccbc691b7c13de5cba69'
            'e7250be7c078053345699250433b7164751d3e457155bd35508c7d1660f459be')

prepare() {
  cd $_pkgname-$pkgver
  # Upstream 3.8 branch
  patch -Np1 -i ../imap-smtp.patch
  patch -Np1 -i ../smtp-auth-plain.patch
}
 
build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --libexec=/usr/lib/gnome-online-accounts \
    --disable-google \
    --enable-owncloud \
    --disable-facebook \
    --disable-windows-live \
    --disable-exchange \
    --disable-flickr \
    --enable-imap-smtp \
    --disable-kerberos
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: