# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=evolution-data-server

pkgver=3.26.2.1
pkgrel=3.nonprism1
_commit=7149f838ab4a908c1a8fc71fcac3a769b3043895  # tags/EVOLUTION_DATA_SERVER_3_26_2_1^0
arch=(i686 x86_64)

pkgdesc="Centralized access to appointments and contacts, without libgdata support"
url="https://wiki.gnome.org/Apps/Evolution"
license=(GPL)

depends=(gnome-online-accounts nss krb5 libgweather libical db libphonenumber)
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism")

source=("git+https://git.gnome.org/browse/evolution-data-server#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
}

build() {
  cd $pkgname

  cmake . -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIBEXEC_INSTALL_DIR=/usr/lib/$pkgname \
    -DSYSCONF_INSTALL_DIR=/etc \
    -DENABLE_INTROSPECTION=ON \
    -DENABLE_VALA_BINDINGS=ON \
    -DENABLE_UOA=OFF \
    -DENABLE_GOOGLE=OFF \
    -DHAVE_LIBGDATA=OFF \
    -DENABLE_GOOGLE_AUTH=OFF \
    -DENABLE_GTK_DOC=ON \
    -DWITH_PHONENUMBER=ON
  ninja
}

check() {
  cd $pkgname
  # libedata-book tests fail because they try to
  # mkdir /usr/lib/evolution-data-server/camel-providers
  ninja test || :
}

package() {
  cd $pkgname
  DESTDIR="$pkgdir" ninja install
}