# $Id$
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

# parabola changes and rationale:
#  - removed libgdata support

pkgname=evolution-data-server
pkgver=3.26.4
pkgrel=1.nonprism1
pkgdesc="Centralized access to appointments and contacts, without libgdata support"
url="https://wiki.gnome.org/Apps/Evolution"
arch=(x86_64 i686 armv7h)
depends=(gnome-online-accounts nss krb5 libgweather libical db libphonenumber)
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
license=(GPL)
_commit=24e636756ef38f485798e47e32bc4c12dd8ec0ad  # tags/3.26.4^0
source=("git+https://git.gnome.org/browse/evolution-data-server#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  cd $pkgname

  cmake . -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIBEXEC_INSTALL_DIR=/usr/lib/$pkgname \
    -DSYSCONF_INSTALL_DIR=/etc \
    -DENABLE_INTROSPECTION=ON \
    -DENABLE_VALA_BINDINGS=ON \
    -DENABLE_UOA=OFF \
    -DENABLE_GOOGLE=OFF \
    -DHAVE_LIBGDATA=OFF \
    -DENABLE_GOOGLE_AUTH=OFF \
    -DENABLE_GTK_DOC=ON \
    -DWITH_PHONENUMBER=ON
  ninja
}

check() {
  cd $pkgname
  # libedata-book tests fail because they try to
  # mkdir /usr/lib/evolution-data-server/camel-providers
  ninja test || :
}

package() {
  cd $pkgname
  DESTDIR="$pkgdir" ninja install
}