# $Id: PKGBUILD 194415 2013-09-16 09:02:51Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

_pkgname=empathy
pkgname=empathy-nonprism
pkgver=3.8.4
pkgrel=1
pkgdesc="A GNOME instant messaging client using the Telepathy framework, without telepathy-haze recommendation"
arch=(i686 x86_64)
url="http://live.gnome.org/Empathy"
license=(GPL2)
depends=(clutter-gst clutter-gtk folks gcr iso-codes libcanberra libpulse webkitgtk3 telepathy-farstream telepathy-glib telepathy-logger telepathy-mission-control)
makedepends=(intltool itstool docbook-xsl python2)
optdepends=('telepathy-gabble: XMPP/Jabber support'
            'telepathy-idle: IRC support'
            'telepathy-salut: Link-local XMPP support'
            'telepathy-rakia: SIP support')
options=('!libtool' '!makeflags')
groups=(gnome)
install=empathy.install
replaces=("$_pkgname" 'empathy-coherence')
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=(http://ftp.gnome.org/pub/GNOME/sources/$_pkgname/${pkgver:0:3}/$_pkgname-$pkgver.tar.xz)
sha256sums=('cbc4934ce838e3d697616b5c36b070d2fc4fc57f84fd654c2f2cb2b8b650f5c9')

build() {
  cd $_pkgname-$pkgver
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
      --sysconfdir=/etc  \
      --libexecdir=/usr/lib/empathy \
      --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}