# $Id: PKGBUILD 105298 2014-02-04 18:30:40Z jlichtblau $
# Maintainer (Arch): Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor (Arch): Kaiting Chen <kaitocracy@gmail.com>
# Contributor (Arch): uvok <uvok at online dot de>
# Contributor (Arch): Urist <9362773 at gmail.com>

_pkgname=bti
pkgname=bti-nonprism
pkgver=034
pkgrel=1
pkgdesc='Console client for status.net, without Twitter support'
arch=('i686' 'x86_64' 'mips64el')
url='http://gregkh.github.com/bti/'
license=('GPL')
depends=('pcre' 'libxml2' 'curl' 'liboauth' 'json-c')
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
replaces=($_pkgname)
source=(http://www.kernel.org/pub/software/web/$_pkgname/$_pkgname-$pkgver.tar.xz
        nonprism.patch)
sha256sums=('8b4a1a11f529f83956468acadaea9d11db4f03e82afe07fecb84b2d00e9eae83'
            '86eab6c949e3c19d3a4088fac78fba4709845e9d5871b12c17a944127347498c')

prepare() {
  cd "${srcdir}"/$_pkgname-$pkgver
  patch -Np1 -i ${srcdir}/nonprism.patch
}

build() {
  cd "${srcdir}"/$_pkgname-$pkgver
  ./configure --prefix=/usr

  make
}

package() {
  cd "${srcdir}"/$_pkgname-$pkgver
  
  make DESTDIR="${pkgdir}" install
}