# $Id: PKGBUILD 237316 2015-04-17 18:19:58Z andyrtr $

# Contributor (Arch): FUBAR <mrfubar@gmail.com>
# Contributor (Arch): simo <simo@archlinux.org>
# Contributor (Arch): Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Gaetan Bisson <bisson@archlinux.org>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=bitlbee
pkgver=3.2.2
pkgrel=2.parabola1.nonprism1
pkgdesc='Brings XMPP to IRC, without nonfree Skype support and support for unsafe and dangerous for privacy protocols'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gnutls' 'glib2')
makedepends=('asciidoc' 'libotr')
optdepends=('libotr: for OTR encryption support')
replaces=("${pkgname}-libre" "${pkgname}-parabola" "${pkgname}-coherence" "${pkgname}-libre-nonprism" "${pkgname}-nonprism")
conflicts=("${pkgname}-libre" "${pkgname}-parabola" "${pkgname}-coherence" "${pkgname}-libre-nonprism" "${pkgname}-nonprism")
source=("http://get.bitlbee.org/src/$pkgname-$pkgver.tar.gz"
        'bitlbee.tmpfiles')
sha1sums=('7e3cfe2b6bf4e8e603c74e7587307a6f5d267e9c'
          '3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
        'etc/bitlbee/motd.txt')
install=bitlbee.install

build() {
  cd "$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --etcdir=/etc/bitlbee \
    --sbindir=/usr/bin \
    --pidfile=/run/bitlbee/bitlbee.pid \
    --ipcsocket=/run/bitlbee/bitlbee.sock \
    --systemdsystemunitdir=/usr/lib/systemd/system \
    --jabber=1 \
    --msn=0 \
    --oscar=0 \
    --yahoo=0 \
    --twitter=0 \
    --ssl=gnutls \
    --strip=0 \
    --otr=plugin \
    --skype=0

  make
}

package() {
  make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev,-systemd}

  install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
  install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}