# $Id: PKGBUILD 141668 2011-11-02 03:17:12Z eric $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: György Balló <ballogy@freestart.hu>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=banshee
pkgname=banshee-nonprism
pkgver=2.6.2
pkgrel=3
pkgdesc="Music management and playback for GNOME, without gdata-sharp support"
arch=('i686' 'x86_64')
url="http://banshee.fm/"
license=('MIT')
depends=(libxxf86vm gst-plugins-base-libs mono-addins dbus-sharp-glib webkitgtk2 libsoup-gnome taglib-sharp gudev-sharp gkeyfile-sharp gconf-sharp libmtp libgpod mono-zeroconf desktop-file-utils hicolor-icon-theme media-player-info gst-plugins-bad mono-upnp)
makedepends=('intltool' 'gnome-doc-utils' 'gtk-sharp-beans' 'gnome-common')
optdepends=('gst-plugins-good: Extra media codecs'
            'gst-plugins-ugly: Extra media codecs'
            'gst-libav: Extra media codecs'
            'brasero: CD burning')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
install=$_pkgname.install
source=(http://download.gnome.org/sources/$_pkgname/2.6/$_pkgname-$pkgver.tar.xz
        Initial-port-to-GStreamer-1.0.patch
        Remove-build-time-enable-gapless-playback-option.patch)
md5sums=('12dbb8a996783f7081d538062a8589b7'
         '16cbe2ef60e6f9b22015585bb3209648'
         '0bf7ee4241b12538779c9ecc401d142a')

prepare() {
  cd $_pkgname-$pkgver
  patch -p1 -i ../Initial-port-to-GStreamer-1.0.patch
  patch -p1 -i ../Remove-build-time-enable-gapless-playback-option.patch
}

build() {
  export MONO_SHARED_DIR="$srcdir/.wabi"
  mkdir -p "$MONO_SHARED_DIR"

  cd $_pkgname-$pkgver

  # Disable youtube extension because it needs gdata-sharp to works
  MCS=/usr/bin/dmcs ./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-docs \
              --disable-static \
              --disable-scrollkeeper \
              --disable-schemas-install \
              --disable-boo \
              --disable-youtube \
              --with-vendor-build-id=Parabola
  make
}

package() {
  export MONO_SHARED_DIR="$srcdir/.wabi"
  mkdir -p "$MONO_SHARED_DIR"

  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -D -m644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/COPYING"
}