# $Id: PKGBUILD 190799 2013-07-16 22:56:09Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=xscreensaver
pkgname=xscreensaver-libre
pkgver=5.22
pkgrel=1
pkgdesc="Screen saver and locker for the X Window System, without nonfree asm files"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libglade' 'xorg-appres' 'perl-libwww')
makedepends=('bc' 'libxpm' 'gdm')
optdepends=('gdm: for login manager support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
backup=('etc/pam.d/xscreensaver')
source=(http://www.jwz.org/xscreensaver/${_pkgname}-${pkgver}.tar.gz \
        xscreensaver-add-electricsheep.diff LICENSE)
sha1sums=('b1d7f97d9b60d9c68c0f3e019cad885f5c7bd6ec'
          'e8dc57b6471fb3867ee099304ac6bf628351cb98'
          '4209ea586b204fd1d81c382a0522c654f9fd9134')

prepare() {
  cd ${_pkgname}-${pkgver}
  patch -p0 -i "${srcdir}/xscreensaver-add-electricsheep.diff"

  # Deleting dmsc.asm file due which don't have source code supplied
  rm -v hacks/images/m6502/dmsc.asm
}

build() {
  cd ${_pkgname}-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
    --with-pam --with-login-manager --with-gtk --with-gl \
    --without-gle --with-pixbuf --with-jpeg
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  install -d "${pkgdir}/etc/pam.d"
  make install_prefix="${pkgdir}" install
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
  chmod 755 "${pkgdir}/usr/bin/xscreensaver"
  echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}