# $Id: PKGBUILD 71681 2010-03-08 12:06:26Z jgc $
# Maintainer: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=xorg-fonts-75dpi-libre
pkgver=1.0.2
pkgrel=1
pkgdesc="X.org 75dpi fonts"
arch=(any)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=(xorg-fonts-encodings xorg-fonts-alias xorg-font-utils fontconfig)
groups=('xorg')
provides=("xorg-fonts-75dpi=$pkgver")
conflicts=('xorg-fonts-75dpi')
replaces=('xorg-fonts-75dpi')
install=xfonts.install
source=(${url}/releases/individual/font/font-adobe-75dpi-1.0.2.tar.bz2
        ${url}/releases/individual/font/font-bitstream-75dpi-1.0.2.tar.bz2)

build() {
  cd "${srcdir}"
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  for dir in *; do
    if [ -d "${dir}" ]; then
      pushd "${dir}"
      ./configure --prefix=/usr \
          --with-fontdir=/usr/share/fonts/75dpi || return 1
      make || return 1
      make DESTDIR="${pkgdir}" install || return 1
      install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.${dir%-75dpi-*}" || return 1
      popd
    fi
  done
  rm -f "${pkgdir}"/usr/share/fonts/75dpi/fonts.*
}
md5sums=('73e8e5f04943e54b69503dcd90821a5f'
         'e51e4ed02a7c09022134ce1f6714b277')