# $Id: PKGBUILD 183738 2016-07-23 00:24:28Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Alexander Fehr <pizzapunk gmail com>
# Contributor (Arch): Andrew Simmons <andrew.simmons@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgbase=xarchiver
pkgname=(xarchiver xarchiver-gtk2)
pkgver=0.5.4.7
pkgrel=1.parabola1
pkgdesc="GTK+ frontend to various command line archivers, without nonfree unrar support"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/ib/xarchiver"
license=('GPL')
depends=('gtk2' 'gtk3')
makedepends=('docbook-xsl' 'intltool' 'xmlto')
optdepends=('zip: ZIP support'
            'unzip: ZIP support'
            'p7zip: 7z support'
            'lzop: LZOP support'
            'cpio: RPM support')
source=(https://github.com/ib/xarchiver/archive/$pkgbase-$pkgver.tar.gz
        libre.patch)
sha256sums=('124eeccd819419c3d8f2935a78a3ad0ad47174bf7ef641441341e3aa32ea8f11'
            '095e01b397f92407c7a2b7d1de91c0c14dd1494ebf5f5ac9e1d4410c12eb41da')

prepare() {
  cd $pkgbase-$pkgbase-$pkgver

  # Remove nonfree unRAR support
  patch -p1 -i ../libre.patch
  rm -v src/rar.{c,h}

  ./autogen.sh
}

build() {
  # GTK+ 3 version
  [ -d gtk3 ] || cp -r $pkgbase-$pkgbase-$pkgver gtk3
  cd gtk3
  ./configure --prefix=/usr --libexecdir=/usr/lib/xfce4
  make -j1

  cd "$srcdir"
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgbase-$pkgver gtk2
  cd gtk2
  ./configure --prefix=/usr --libexecdir=/usr/lib/xfce4 --enable-gtk2
  make -j1
}

package_xarchiver() {
  depends=('gtk3')
  conflicts=('xarchiver-libre')
  replaces=('xarchiver-libre')

  cd gtk3
  make DESTDIR="$pkgdir" install
}

package_xarchiver-gtk2() {
  pkgdesc+=' (GTK+ 2 version)'
  depends=('gtk2')
  conflicts=('xarchiver')

  cd gtk2
  make DESTDIR="$pkgdir" install
}