# Maintainer (Arch): Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor (Arch): kappa <kappacurve@gmail.com>
# Maintainer: Márcio Silva <coadde@hyperbola.info>

pkgname=wings3d
pkgver=2.2.4
pkgrel=1
pkgrel+=.parabola1
pkgdesc='3D modeler using the winged edge data structure'
pkgdesc+=', without nonfree kerkythea render support'
arch=(x86_64)
arch+=(i686 armv7h)
url='http://www.wings3d.com/'
license=(GPL)
depends=(erlang erlang-cl erlang-sdl)
makedepends=(gendesk imagemagick)
optdepends=('povray: render scenes with POV-Ray')
conflicts=("${pkgname}-libre")
replaces=("${pkgname}-libre")
source=("https://downloads.sourceforge.net/project/wings/wings/$pkgver/wings-$pkgver.tar.bz2"
        "$pkgname.sh")
sha256sums=('4325a4c58df77a2b109cbd0046b427e2d3f151d5526f8c2f0848e04db48b95f5'
            '8e5e8f31d47ea55a0e9d311b7cc0eaac4e6050ac40506d3548b6ebae5d3618be')
_p=${pkgname%3d}-$pkgver

prepare() {
  gendesk -f -n \
    --name Wings3D \
    --pkgname $pkgname \
    --pkgdesc "$pkgdesc" \
    --genericname '3D Modeler' \
    --categories 'Graphics;3DGraphics'

  # Convert the icon in a reproducable way
  convert +set date:create +set date:modify "$_p"/win32/wings.ico $pkgname.png

  # Path fix for building wpc_lwo
  ln -s "$_p" "$_p"/plugins_src/import_export/wings
  ln -s "$_p" wings

  sed -i 's/-Werror//' "$_p"/{src,e3d,plugins_src/import_export}/Makefile
}

build() {
  export ESDL_PATH="$(echo /usr/lib/erlang/lib/esdl-*)"
  export ERL_LIBS="$srcdir"

  make -C "$_p" all lang
}

package() {
  install -Dm755 $pkgname.sh "$pkgdir/usr/bin/$pkgname"

  install -Dm644 $pkgname.desktop \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 $pkgname-3.png "$pkgdir/usr/share/pixmaps/$pkgname.png"

  install -d "$pkgdir/usr/lib/$pkgname"
  for subdir in e3d ebin icons plugins psd shaders src textures tools; do
    cp -r "$_p"/$subdir/ "$pkgdir/usr/lib/$pkgname"
  done
  msg 'remove nonfree kerkythea render support plugin'
  rm -v $pkgdir/usr/lib/$pkgname/plugins/import_export/wpc_kerky.beam
}

# getver: -u=2 github.com/dgud/wings/releases
# vim: ts=2 sw=2 et: