# $Id: PKGBUILD 95697 2013-08-15 18:20:27Z arodseth $
# Maintainer (Arch): Alexander Rødseth <rodseth@gmail.com>
# Contributor (Arch): kappa <kappacurve@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

_name=wings
_pkgname=${_name}3d
pkgname=$_pkgname-libre
pkgver=1.5.2
pkgrel=1.1
pkgdesc='3D modeling program, without nonfree kerkythea render support'
arch=('x86_64' 'i686' 'mips64el')
url='http://www.wings3d.com/'
license=('GPL')
depends=('erlang-sdl' 'erlang-cl' 'bash' 'desktop-file-utils' 'erlang')
makedepends=('gendesk')
optdepends=('povray: rendering support via POV-Ray')
provides=("$_pkgname")
conflicts=("$_pkgname")
replaces=("$_pkgname")
install=$_pkgname.install
source=("$_pkgname-$pkgver.tar.gz::https://github.com/dgud/wings/archive/v$pkgver.tar.gz"
        "$_pkgname.sh"
        "$_pkgname.png::http://img299.imageshack.us/img299/2538/wingsiconblackshiningew5.png")
sha256sums=('d86980e4fa91a04ca96b989b0dcba53a37c8cfda4e6d98accb8e7bd9a289094b'
            '46513cd05f8b6e778120af4a87b239c5250799c17b591592893d98cbf082359e'
            '6658977cc3bc8db2c9358edf3a2d6cb6bb8084c9a1d96ca573a83dd4e8781f1a')

prepare() {
  gendesk --pkgname "$_pkgname" --pkgdesc "$pkgdesc" \
    --genericname '3D Modeler' --categories 'Graphics;3DGraphics'

  cd "$_name-$pkgver"
  sed -i "s|v1[.]2[.]x[.]y[.]WINGS|v$pkgver.$pkgrel.PARABOLA|" WINGS-VERSION-GEN
}

build() {
  cd "$_name-$pkgver"

  export ESDL_PATH=$(echo /usr/lib/erlang/lib/esdl-*)
  make
  make lang
}

package() {
  cd "$_name-$pkgver"

  mkdir -p "$pkgdir/usr/lib/$_pkgname"
  for subdir in ebin fonts patches plugins shaders textures; do
    cp -r "$srcdir/$_name-$pkgver/$subdir/" "$pkgdir/usr/lib/$_pkgname"
  done
  cd "$srcdir"
  install -Dm755 "$_pkgname.sh" "$pkgdir/usr/bin/$_pkgname"
  install -Dm644 "$_pkgname.png" "$pkgdir/usr/share/pixmaps/$_pkgname.png"
  install -Dm644 "$_pkgname.desktop" \
    "$pkgdir/usr/share/applications/$_pkgname.desktop"

  msg 'remove nonfree kerkythea render support plugin'
  rm -v $pkgdir/usr/lib/wings3d/plugins/import_export/wpc_kerky.beam

  msg 'remove obsolete yafray render support plugin'
  rm -v $pkgdir/usr/lib/wings3d/plugins/import_export/wpc_yafray{.beam,_{de,en,fr,ko}.lang}
}

# vim:set ts=2 sw=2 et: