# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Maintainer (Parabola): Jorge López <jorginho@lavabit.com>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

pkgbase=virtualbox-libre-modules
pkgname=('virtualbox-libre-host-modules' 'virtualbox-libre-guest-modules')
pkgver=4.2.4
pkgrel=3
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL')
makedepends=('linux-libre-headers'
             "virtualbox-libre-host-source>=$pkgver"
             "virtualbox-libre-guest-source>=$pkgver"
             'expac')

build() {
  # current kernel libre version
  _kernver=$(expac -Q '%v' linux-libre-headers)-LIBRE
  # dkms need modification to be run as user
  cp -r /var/lib/dkms .
  echo "dkms_tree='$srcdir/dkms'" > dkms.conf
  # build host modules
  msg2 'Host modules'
  dkms --dkmsframework dkms.conf build "vboxhost/$pkgver" -k "$_kernver"
  # build guest modules
  msg2 'Guest modules'
  dkms --dkmsframework dkms.conf build "vboxguest/$pkgver" -k "$_kernver"
}

package_virtualbox-libre-host-modules(){
  pkgdesc='Host kernel libre modules for VirtualBox'
  depends=('linux-libre>=3.7' 'linux-libre<3.8')
  provides=("virtualbox-host-modules=${pkgver}")
  replaces=('virtualbox-host-modules' 'virtualbox-modules' 'virtualbox-libre-modules')
  conflicts=('virtualbox-host-modules' 'virtualbox-modules' 'virtualbox-libre-modules')
  install=virtualbox-libre-host-modules.install

  _kernver=$(expac -Q '%v' linux-libre-headers)-LIBRE
  _extraver=extramodules-${_kernver%.*}-LIBRE

  install -dm755 "$pkgdir/usr/lib/modules/$_extraver"
  cd "dkms/vboxhost/$pkgver/$_kernver/$CARCH/module"
  install -m644 * "$pkgdir/usr/lib/modules/$_extraver"
  find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
  sed -ie "s/EXTRAMODULES='.*'/EXTRAMODULES='$_extraver'/" "$startdir/virtualbox-libre-host-modules.install"
}

package_virtualbox-libre-guest-modules(){
  pkgdesc='Guest kernel libre modules for VirtualBox'
  license=('GPL')
  depends=('linux-libre>=3.7' 'linux-libre<3.8')
  provides=("virtualbox-guest-modules=${pkgver}")
  replaces=('virtualbox-guest-modules' 'virtualbox-archlinux-modules' 'virtualbox-parabola-modules')
  conflicts=('virtualbox-guest-modules' 'virtualbox-archlinux-modules' 'virtualbox-parabola-modules')
  install=virtualbox-libre-guest-modules.install

  _kernver=$(expac -Q '%v' linux-libre-headers)-LIBRE
  _extraver=extramodules-${_kernver%.*}-LIBRE

  install -dm755 "$pkgdir/usr/lib/modules/$_extraver"
  cd "dkms/vboxguest/$pkgver/$_kernver/$CARCH/module"
  install -m644 * "$pkgdir/usr/lib/modules/$_extraver"
  find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
  sed -ie "s/EXTRAMODULES='.*'/EXTRAMODULES='$_extraver'/" "$startdir/virtualbox-libre-guest-modules.install"
}


# vim:set ts=2 sw=2 et: