# $Id: PKGBUILD 222207 2017-04-11 12:38:23Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Daniel Micay <danielmicay@gmail.com>
# Contributor (Arch): Jonathan Wiersma <archaur at jonw dot org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgbase=virt-manager
pkgname=virt-install
pkgver=1.5.1
pkgrel=1.parabola1
pkgdesc="Console user interface for managing virtual machines, without non-FSDG compliant distros and operating systems support"
arch=('any')
url="http://virt-manager.org/"
license=('GPL')
depends=('python2-gobject' 'libvirt-glib' 'libvirt-python2'
	 'python2-requests' 'python2-ipaddr' 'libosinfo')
makedepends=('intltool' 'python2-cairo')
source=("https://virt-manager.org/download/sources/virt-manager/virt-manager-$pkgver.tar.gz"
        'libre.patch')
sha512sums=('e0da3b879ea33a8c394c33df85cadac4fbb9cfed65f9a904c5d9bf07232e29f8c96b5242e3f94cae390b7b5d7a20e1c25c3867962f0a39de40e71dc00013d32b'
            'd1ae2affc590921375f4b0ffd3e412032b2d98e63056df0546eff53b7706e3b5aeaaf2d1ba6fa6dcc86bc514404df30b06cc4495a73a37b824184f0ba3a2fc81')

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  patch -p1 -i ../libre.patch
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py build
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py --no-update-icon-cache --no-compile-schemas install --root "$pkgdir"
  python2 -m compileall "${pkgdir}/usr/share/virt-manager"
  python2 -O -m compileall "${pkgdir}/usr/share/virt-manager"
  rm "${pkgdir}/usr/bin/virt-manager"
}