# $Id: PKGBUILD 195858 2016-11-14 17:58:58Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Daniel Micay <danielmicay@gmail.com>
# Contributor (Arch): Jonathan Wiersma <archaur at jonw dot org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgbase=virt-manager
pkgname=virt-install
pkgver=1.4.0
pkgrel=2.parabola5
pkgdesc="Console user interface for managing virtual machines, without non-FSDG compliant distros and operating systems support"
arch=('any')
url="http://virt-manager.org/"
license=('GPL')
depends=('python2' 'libvirt-python' 'libxml2' 'libvirt'
	 'libosinfo' 'python2-ipaddr' 'python2-gobject' 'python2-requests')
makedepends=('intltool>=0.35.0'
	     'dbus-python' 'gtk-vnc' 'rarian'
	     'yajl' 'librsvg' 'libuser' 'python2-cairo'
	     'python2-ipy' 'newt-syrup' 'openbsd-netcat' 'x11-ssh-askpass'
	     'graphite' 'spice-gtk3'
	     'libvirt-glib' 'vte3')
source=("https://virt-manager.org/download/sources/virt-manager/virt-manager-$pkgver.tar.gz"
        'libre.patch')
sha256sums=('bf31a40cc48500cbf87a0e93a5838fc3f6ce4e2fa03f8bce6aa2615625e6caca'
            'df2961a0efe68c07f29cf2578f986432fd3a2c0db289b9630866faa24f116211')

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  patch -p1 -i ../libre.patch
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py build
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py --no-update-icon-cache --no-compile-schemas install --root "$pkgdir"
  python2 -m compileall "${pkgdir}/usr/share/virt-manager"
  python2 -O -m compileall "${pkgdir}/usr/share/virt-manager"
  rm "${pkgdir}/usr/bin/virt-manager"
}