# $Id: PKGBUILD 208834 2017-01-24 13:42:38Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Daniel Micay <danielmicay@gmail.com>
# Contributor (Arch): Jonathan Wiersma <archaur at jonw dot org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgbase=virt-manager
pkgname=virt-install
pkgver=1.4.1
pkgrel=1.parabola1
pkgdesc="Console user interface for managing virtual machines, without non-FSDG compliant distros and operating systems support"
arch=('any')
url="http://virt-manager.org/"
license=('GPL')
depends=('python2' 'libvirt-python' 'libxml2' 'libvirt'
	 'libosinfo' 'python2-ipaddr' 'python2-gobject' 'python2-requests'
	 'cpio')
makedepends=('intltool>=0.35.0'
	     'dbus-python' 'gtk-vnc' 'rarian'
	     'yajl' 'librsvg' 'libuser' 'python2-cairo'
	     'python2-ipy' 'newt-syrup' 'openbsd-netcat' 'x11-ssh-askpass'
	     'graphite' 'spice-gtk3'
	     'libvirt-glib' 'vte3')
source=("https://virt-manager.org/download/sources/virt-manager/virt-manager-$pkgver.tar.gz"
        'libre.patch')
sha256sums=('e6c549999f14fbda210c07821910bfa35c086542e166f8b00d7c83717e9f3944'
            'b7842786933f2bbe9ee612f4db7fc5456da8bd6a849fb46044a148d57e1a95b0')

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"
  patch -p1 -i ../libre.patch
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py build
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"
  python2 setup.py --no-update-icon-cache --no-compile-schemas install --root "$pkgdir"
  python2 -m compileall "${pkgdir}/usr/share/virt-manager"
  python2 -O -m compileall "${pkgdir}/usr/share/virt-manager"
  rm "${pkgdir}/usr/bin/virt-manager"
}