# Maintainer: Cedric Girard <girard.cedric@gmail.com>
# Contributor: N30N <archlinux@alunamation.com>

pkgname=unar
pkgver=1.4
pkgrel=1
pkgdesc="An Objective-C application for uncompressing archive files"
arch=('x86_64' 'i686' 'mips64el')
url="http://unarchiver.c3.cx/"
license=('LGPL2.1')
depends=('gnustep-base' 'openssl' 'bzip2' 'icu' 'gcc-libs' 'zlib')
makedepends=('gcc-objc')
replaces=("unarchiver")
conflicts=("unarchiver")
provides=("unarchiver")
source=("http://theunarchiver.googlecode.com/files/${pkgname}${pkgver}_src.zip"
        "native_obj_exceptions.patch")

build() {
  cd "$srcdir/The Unarchiver"

  patch -p1 < ../native_obj_exceptions.patch

  cd XADMaster
  . /usr/share/GNUstep/Makefiles/GNUstep.sh
  make -f Makefile.linux
}

package() {
  cd "$srcdir/The Unarchiver/XADMaster"
  install -d "$pkgdir/usr/bin/"
  install -m755 unar lsar "$pkgdir/usr/bin/"

  cd "$srcdir/The Unarchiver/Extra"
  install -d "$pkgdir/usr/share/man/man1"
  gzip -c lsar.1 > "$pkgdir/usr/share/man/man1"/lsar.1.gz
  gzip -c unar.1 > "$pkgdir/usr/share/man/man1"/unar.1.gz
}

# vim:set ts=2 sw=2 et:
md5sums=('ae5233dd835229f867f0948d28dde0d6'
         '4fa4ecc6e4ba14d3b6952d064e728511')