# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer (Arch): Cedric Girard <girard.cedric@gmail.com>
# Contributor (Arch): N30N <archlinux@alunamation.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>

pkgname=unar

pkgver=1.10.1
pkgrel=8
arch=(x86_64 i686 armv7h)

pkgdesc="An Objective-C application for uncompressing archive files"
url="http://unarchiver.c3.cx/"
license=(LGPL2.1)

depends=(gnustep-base openssl bzip2 gcc-libs zlib)
depends_x86_64=("icu>=60" "icu<61")
depends_i686=("icu>=60" "icu<61")
depends_armv7h=("icu>=60" "icu<61")
makedepends=(gcc-objc unzip)
replaces=(unarchiver unrar)
conflicts=(unarchiver unrar)
provides=(unarchiver unrar)

source=("$pkgname-$pkgver.zip::https://theunarchiver.com/downloads/TheUnarchiverSource.zip"
        "native_obj_exceptions.patch")
sha256sums=('ac4cedf9b49375c0f805bda010fa03629d05ab283a0a8e35bf2dd01ae477e0a1'
            '8b5be982e9cfd8cb800443d0f11c1e474ccfa3d9d81e1e869ee84b8f73f74cdd')
noextract=("$pkgname-$pkgver.zip")

prepare()
{
  mkdir $pkgname-$pkgver
  cd $pkgname-$pkgver
  unzip ../$pkgname-$pkgver.zip

  patch -p1 < "$srcdir/native_obj_exceptions.patch"

  cd XADMaster
  . /usr/share/GNUstep/Makefiles/GNUstep.sh
}

build() {
  cd "$srcdir/$pkgname-$pkgver/XADMaster"
  make -f Makefile.linux
}

package() {
  cd "$srcdir/$pkgname-$pkgver/XADMaster"
  install -d "$pkgdir/usr/bin/"
  install -m755 unar lsar "$pkgdir/usr/bin/"

  cd "$srcdir/$pkgname-$pkgver/Extra"
  install -d "$pkgdir/usr/share/man/man1"
  gzip -c lsar.1 > "$pkgdir/usr/share/man/man1"/lsar.1.gz
  gzip -c unar.1 > "$pkgdir/usr/share/man/man1"/unar.1.gz
}