# U-Boot: UDOO
# Maintainer (Arch): Kevin Mihelich <kevin@archlinuxarm.org>
# Contributor: André Silva <emulatorman@parabola.nu>

buildarch=4

_pkgbase=linux-libre-grsec
pkgbase=uboot-udoo-${_pkgbase}
pkgname=("uboot-udoo-dual-${_pkgbase}" "uboot-udoo-quad-${_pkgbase}")
pkgver=2015.01
pkgrel=1.2
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('bc')
depends=('linux-libre-grsec')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        '0002-kernel-add-support-for-gcc-5.patch')
md5sums=('7f08dc9e98a71652bd6968888ed6ec95'
         'b0a091d406f00f47a18d6c1c0926c939'
         '721a46867e189d8dedc6b6f86a536a34')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
  patch -Np1 -i ../0002-kernel-add-support-for-gcc-5.patch
}

build() {
  cd u-boot-${pkgver}
  
  unset CFLAGS CXXFLAGS LDFLAGS
  
  mkdir bins
  for i in dl quad; do
    make distclean
    make udoo_${i}_config
    make
    mv u-boot.imx bins/u-boot-${i}.imx
  done
}

package_uboot-udoo-dual-linux-libre-grsec() {
  pkgdesc="U-Boot for UDOO Dual (built for the linux-libre-grsec kernel package)"
  replaces=('uboot-udoo-dual')
  install=${pkgname}.install

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp u-boot-${pkgver}/bins/u-boot-dl.imx "${pkgdir}/boot/${pkgname}"/u-boot.imx
}

package_uboot-udoo-quad-linux-libre-grsec() {
  pkgdesc="U-Boot for UDOO Quad (built for the linux-libre-grsec kernel package)"
  replaces=('uboot-udoo-quad')
  install=${pkgname}.install

  mkdir -p "${pkgdir}/boot/${pkgname}"
  cp u-boot-${pkgver}/bins/u-boot-quad.imx "${pkgdir}/boot/${pkgname}"/u-boot.imx
}