# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

_basekernel=4.14
_archrel=45
_parabolarel=2

pkgname=tp_smapi
_pkgname=tp-smapi
pkgver=0.42
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
_extramodules=extramodules-${_basekernel}
pkgdesc="Modules for ThinkPad's SMAPI functionality (built for the linux-libre kernel package)"
arch=('i686' 'x86_64')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')

# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
depends=("linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
makedepends=("linux-libre-headers>=${_basekernel}" "linux-libre-headers<${_toohigh}")
makedepends+=('libelf')

replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")

source=("${pkgname}-${_pkgname}-${pkgver}.tar.gz::https://github.com/evgeni/${pkgname}/archive/${_pkgname}/${pkgver}.tar.gz")
sha256sums=('cd28bf6ee21b2c27b88d947cb0bfcb19648c7daa5d350115403dbcad05849381')

build() {
  cd "${pkgname}-${_pkgname}-${pkgver}"

  # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
  # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules

  make HDAPS=1 KVER="$(</usr/lib/modules/${_extramodules}/version)" EXTRA_CFLAGS=
}

package() {
  cd "${pkgname}-${_pkgname}-${pkgver}"

  # install kernel modules
  find . -name "*.ko" -exec install -Dt "${pkgdir}/usr/lib/modules/${_extramodules}" {} +

  # compress kernel modules
  find "${pkgdir}" -name "*.ko" -exec gzip -9 {} +

  # load module on startup
  install -dm 755 "${pkgdir}/usr/lib/modules-load.d"
  echo ${pkgname} > "${pkgdir}/usr/lib/modules-load.d/${pkgname}.conf"
}