# Maintainer: Michał Masłowski

pkgname=texlive-texmf-libre
pkgver=2011
pkgrel=1
epoch=
pkgdesc="TeXLive files used by TeX and related programs"
arch=('any')
url="http://tug.org/texlive/"
license=('GPL')
groups=()
depends=('texlive-bin-libre')
provides=('texlive-bibtexextra' 'texlive-core' 'texlive-fontsextra' 'texlive-formatsextra' 'texlive-games' 'texlive-genericextra' 'texlive-htmlxml' 'texlive-humanities' 'texlive-langcjk' 'texlive-langcyrillic' 'texlive-langextra' 'texlive-langgreek' 'texlive-latexextra' 'texlive-music' 'texlive-pictures' 'texlive-plainextra' 'texlive-pstricks' 'texlive-publishers' 'texlive-science')
conflicts=('texlive-bibtexextra' 'texlive-core' 'texlive-fontsextra' 'texlive-formatsextra' 'texlive-games' 'texlive-genericextra' 'texlive-htmlxml' 'texlive-humanities' 'texlive-langcjk' 'texlive-langcyrillic' 'texlive-langextra' 'texlive-langgreek' 'texlive-latexextra' 'texlive-music' 'texlive-pictures' 'texlive-plainextra' 'texlive-pstricks' 'texlive-publishers' 'texlive-science')
replaces=('texlive-bibtexextra' 'texlive-core' 'texlive-fontsextra' 'texlive-formatsextra' 'texlive-games' 'texlive-genericextra' 'texlive-htmlxml' 'texlive-humanities' 'texlive-langcjk' 'texlive-langcyrillic' 'texlive-langextra' 'texlive-langgreek' 'texlive-latexextra' 'texlive-music' 'texlive-pictures' 'texlive-plainextra' 'texlive-pstricks' 'texlive-publishers' 'texlive-science')
backup=()
options=()
install=texlive.install
source=($pkgname-$pkgver.tar.xz)
noextract=()
md5sums=('7575a6bee3a487bbcf7f8e1e1f215881')

mksource() {
    [ -f texlive-20110705-texmf.tar.xz ] || wget ftp://tug.org/historic/systems/texlive/2011/texlive-20110705-texmf.tar.xz
    tar xf texlive-20110705-texmf.tar.xz
    mv texlive-20110705-texmf "$pkgname-$pkgver"
    cd "$pkgname-$pkgver"
    # We have it in texlive-bin-libre
    rm -rf texmf
    # Generated files, are separately made after installation.
    rm texmf-dist/ls-R
    # MeX-licensed packages.
    rm -rf texmf-dist/{fonts/{map/dvips,{type1,tfm,source}/public},doc/fonts}/cc-pl
    rm -rf texmf-dist/fonts/{map/dvips,{type1,enc,tfm,source}/public}/cs
    rm -rf texmf-dist/{doc,source,tex}/mex
    # Includes code from nonfree PL fonts.  Probably some files could
    # be useful without it, but the license requires including whole
    # original source.
    rm -rf  texmf-dist/{fonts/{tfm,source}/jknappen,doc/fonts}/ec
    # Public domain, will be relicensed in next version.
    rm -rf texmf-dist/{doc,source,tex}/context/third/{account,algorithmic,fixme,games,letter,ruby}
    # No specific free license.
    rm -rf texmf-dist/{doc,source,tex}/latex/{authoraftertitle,clock,fltpage,fnpara}
    rm -rf texmf-dist/{fonts/{tfm,source}/public,doc/fonts,doc/latex}/{euro-ce,ogham}
    # No explicit modification permission.
    rm -rf texmf-dist/{doc,source,tex}/latex/cmdtrack
    # Recommends nonfree software.
    rm -rf texmf-dist/doc/generic/tex-virtual-academy-pl
    # Recommends nonfree fonts and it's not obvious if no right to
    # modify such document is needed.
    rm -rf texmf-dist/doc/fonts/free-math-font-survey
    # No modification.
    rm -rf texmf-dist/doc/plain/gentle
    cd ..
    tar cJf "$pkgname-$pkgver.tar.xz" "$pkgname-$pkgver"
}

build() {
  :
}

package() {
  mkdir -p "$pkgdir/usr/share"
  cp -R "$srcdir/$pkgname-$pkgver/texmf-dist" "$pkgdir/usr/share"
}

# vim:set ts=2 sw=2 et: