# Maintainer: Firmicus <firmicus āt gmx dōt net>
# Maintainer: Rémy Oudompheng <remy@archlinux.org>
# Maintainer (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Contributor (Parabola): André Silva <emulatorman@lavabit.com>

pkgname=texlive-latexextra-libre
_pkgname=texlive-latexextra
pkgver=2012.26807
_revnr=${pkgver#2012.}
pkgrel=1
pkgdesc="TeX Live - Large collection of add-on packages for LaTeX"
license=('GPL')
arch=(any)
depends=('texlive-core')
optdepends=(
  'texlive-pictures: to use the package overpic'
  'openjdk6: for use by ppower4'
)
provides=('texlive-latexextra')
replaces=('texlive-latexextra')
conflicts=('texlive-latexextra')
groups=('texlive-most')
url='http://tug.org/texlive/'
source=("ftp://ftp.archlinux.org/other/texlive/$_pkgname-$pkgver-src.zip" "$_pkgname.maps")
options=('!emptydirs')
options=(!strip)
install=texlive.install
md5sums=('868dc1824391768e120fdd71ba28e520'
         '9e4825f47dac663dd62c4bfa67899e84')

build() {
   # remove nonfree packages
   # No specific free license.
   rm {authoraftertitle,clock,fnpara}.tar.xz
   # Remove them from package list.
   sed -ri '/^(authoraftertitle|fnpara) /d' CONTENTS
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true
}
package() {
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${_pkgname}_${_revnr}.pkgs
   install -m644 $_pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
   #add symlinks that were in texlive-bin:
   install -m755 -d $pkgdir/usr/bin
   ln -s /usr/share/texmf-dist/scripts/authorindex/authorindex $pkgdir/usr/bin/authorindex
   ln -s /usr/share/texmf-dist/scripts/exceltex/exceltex $pkgdir/usr/bin/exceltex
   ln -s /usr/share/texmf-dist/scripts/glossaries/makeglossaries $pkgdir/usr/bin/makeglossaries
   ln -s /usr/share/texmf-dist/scripts/pax/pdfannotextractor.pl $pkgdir/usr/bin/pdfannotextractor
   ln -s /usr/share/texmf-dist/scripts/ppower4/pdfthumb.tlu $pkgdir/usr/bin/pdfthumb
   ln -s /usr/share/texmf-dist/scripts/perltex/perltex.pl $pkgdir/usr/bin/perltex
   ln -s /usr/share/texmf-dist/scripts/pst-pdf/ps4pdf $pkgdir/usr/bin/ps4pdf
   ln -s /usr/share/texmf-dist/scripts/splitindex/perl/splitindex.pl $pkgdir/usr/bin/splitindex
   ln -s /usr/share/texmf-dist/scripts/svn-multi/svn-multi.pl $pkgdir/usr/bin/svn-multi
   ln -s /usr/share/texmf-dist/scripts/vpe/vpe.pl $pkgdir/usr/bin/vpe
   # but ppower4 was a symlink to ppower4.tlu, which was broken, but this is far better:
   (
   cat <<"END"
#!/bin/bash
java -jar /usr/share/texmf-dist/scripts/ppower4/pp4p.jar $@
END
   ) > /tmp/ppower4 
   install -m755 /tmp/ppower4 $pkgdir/usr/bin/
   rm $pkgdir/usr/share/texmf-dist/scripts/glossaries/makeglossaries.bat
   rm $pkgdir/usr/share/texmf-dist/scripts/pst-pdf/ps4pdf.bat*
   rm $pkgdir/usr/share/texmf-dist/scripts/shipunov/biokey2html.bat
}