# Maintainer (Arch): Rémy Oudompheng <remy.archlinux.org>
# Maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: André Silva <emulatorman@parabola.nu>

_pkgname=texlive-fontsextra-libre
pkgname=texlive-fontsextra
pkgver=2014.34817
_revnr=${pkgver#2014.}
pkgrel=1.parabola1
pkgdesc="TeX Live - all sorts of extra fonts, without nonfree add-on packages"
license=('GPL')
arch=(any)
depends=('texlive-core')
groups=('texlive-most')
replaces=('texlive-fontsextra-libre')
conflicts=('texlive-fontsextra-libre')
url='http://tug.org/texlive/'
mksource=("ftp://ftp.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip")
noextract=("$pkgname-$pkgver-src.zip")
source=("https://repo.parabolagnulinux.org/other/$_pkgname/$_pkgname-$pkgver-src.tar.xz" "$pkgname.maps")
options=('!emptydirs')
install=texlive.install
mkmd5sums=('2094b82201b22a816f3b6fe09f373818')
md5sums=('235925b615932426986d3c88bebe8a21'
         '77a2d0f39da91c06a2e9ab6a230fe390')

mksource() {
   mkdir $pkgname-$pkgver
   pushd $pkgname-$pkgver
   bsdtar xfv ../$pkgname-$pkgver-src.zip

   # remove nonfree packages
   # No specific free license.
   rm -v ogham.tar.xz
   # Remove them from package list.
   sed -ri '/^ogham /d' CONTENTS

   popd
}

build() {
   cd $srcdir/$pkgname-$pkgver
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true
}

package() {
   cd $srcdir/$pkgname-$pkgver
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 $srcdir/$pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
}