# Maintainer (Arch): Rémy Oudompheng <remy.archlinux.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>


# parabola changes and rationale:
#  - remvoe nonfree add-on packages


_pkgname=texlive-fontsextra-libre
pkgname=texlive-fontsextra
pkgver=2020.55407
_revnr=${pkgver#2020.}
pkgrel=1
pkgrel+=.par1
pkgdesc="TeX Live - all sorts of extra fonts"
pkgdesc+=", without nonfree add-on packages"
license=('GPL')
arch=(any)
depends=('texlive-core')
groups=('texlive-most')
url='http://tug.org/texlive/'
mksource=("https://sources.archlinux.org/other/texlive/$pkgname-$pkgver-src.zip")
mksha256sums=('25e1060c699f09e02924bf27902b162d7af5a6cc2d0c898f83c09ca0928d9060')
noextract=("$pkgname-$pkgver-src.zip")
source=("https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver-src.tar.xz"{,.sig}
        "$pkgname.maps")
options=('!emptydirs')
sha256sums=('c58eb0df24a6ee0b258ca3088f90ec51a20e5b000f645876913b3d84933537df'
            'SKIP'
            '6346b4a1fc5a2a2e744715ae2e9462a55255e229e59d0e00ab5957d34bd75f99')
validpgpkeys=('1B8C5E87702444D3D825CC8086ED62396D5DBA58'  # Omar Vega Ramos
              '38D33EF29A7691134357648733466E12EC7BA943'  # Isaac David
              '3954A7AB837D0EA9CFA9798925DB7D9B5A8D4B40') # bill-auger


mksource() {
   mkdir $pkgname-$pkgver
   pushd $pkgname-$pkgver
   bsdtar xfv ../$pkgname-$pkgver-src.zip

   # remove nonfree packages
   # no specific free license
   rm -v ogham.tar.xz

   popd
}

prepare() {
   cd $srcdir/$pkgname-$pkgver
   echo -n "   --> extracting all packages... "
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true

   # remove nonfree packages references from package list
   sed -ri '/^ogham /d' CONTENTS
}

package() {
   cd $srcdir/$pkgname-$pkgver
   install -m755 -d "$pkgdir"/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS "$pkgdir"/var/lib/texmf/arch/installedpkgs/${pkgname}_${_revnr}.pkgs
   install -m644 "$srcdir"/$pkgname.maps "$pkgdir"/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 "$pkgdir"/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' "$pkgdir"/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 "$pkgdir"/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' "$pkgdir"/usr/share/'{}' \;
   fi
   if [[ -d "$pkgdir"/usr/share/texmf-dist/scripts ]]; then
     find "$pkgdir"/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
}