# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=stuntrally-data-libre
_pkgname=stuntrally-data
pkgver=2.3
pkgrel=1
pkgdesc="Stunt Rally game with track editor, based on VDrift (data files), without nonfree data files"
arch=('any')
license=('GPL3' 'custom')
url="http://code.google.com/p/vdrift-ogre"
makedepends=('cmake' 'boost' 'libvorbis' 'mygui' 'sdl2' 'enet' 'hicolor-icon-theme' 'libxcursor')
mksource=("$_pkgname-$pkgver.tar.gz::https://github.com/stuntrally/stuntrally/archive/${pkgver}.tar.gz")
source=("https://repo.parabolagnulinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz"
        "$_pkgname-tracks-$pkgver.tar.gz::https://github.com/stuntrally/tracks/archive/${pkgver}.tar.gz"
        libre.patch)
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
mksha256sums=('828ea8e4a8ea73005e88ef015cb9808cc75d0cb50693a0f4a7d8b09edd0765fd')
sha256sums=('2973aa09cd68541784d1df7b5f9f0e29a307078b5a9b33ad467880ebf8f832fb'
            '8da6396abb569fbcf312095a96c2b7cfa92f510900d32b7d7e2fcd9478a7216f'
            'a155c170ff33dd92f4720c2f1214195eea6e5dab774a0939979599ab85f974d8')
mksource() {
  # remove nonfree data files
  cd "${srcdir}/stuntrally-${pkgver}/"

  rm -v data/trees2/tree*.mesh
}

prepare() {
  # remove nonfree references
  patch -Np0 -i "${srcdir}/libre.patch"
}

build() {
  # build the sources
  cd "${srcdir}/stuntrally-${pkgver}/"

  rm -rf build
  mkdir build && cd build

  cmake .. \
      -DCMAKE_INSTALL_PREFIX="/usr" \
      -DSHARE_INSTALL="share/stuntrally"
  make

  # build the tracks
  cd "${srcdir}/tracks-${pkgver}/"

  rm -rf build
  mkdir build && cd build

  cmake .. \
      -DCMAKE_INSTALL_PREFIX="/usr"
  make
}

package() {
  # install the sources
  cd "${srcdir}/stuntrally-${pkgver}/build/"
  make DESTDIR="${pkgdir}" install

  # install the tracks
  cd "${srcdir}/tracks-${pkgver}/build"
  make DESTDIR="${pkgdir}/usr/share/stuntrally/" install

  # clean up
  rm -rf "${pkgdir}/usr/share/stuntrally/tracks/build"
  rm -rf "${pkgdir}/usr/share/icons"
  rm -rf "${pkgdir}/usr/share/applications"
  rm -rf "${pkgdir}/usr/bin"
}