# $Id: PKGBUILD 116546 2014-07-29 18:12:51Z bpiotrowski $
# Maintainer (Arch):  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor (Arch): IgnorantGuru http://igurublog.wordpress.com/contact-ignorantguru/
# Contributor (Arch): ridikulus_rat <the.ridikulus.rat@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Edison Ibañez <arkhan.xxx@gmail.com>

_pkgname=spacefm
pkgname=spacefm-libre
pkgver=0.9.4
pkgrel=2
pkgdesc='Multi-panel tabbed file manager, with unar support'
arch=('i686' 'x86_64' 'mips64el')
url='http://ignorantguru.github.com/spacefm/'
license=('GPL3')
install=$_pkgname.install
depends=('gtk2' 'shared-mime-info' 'desktop-file-utils' 'startup-notification'
         'systemd' 'bash' 'unar')
makedepends=('intltool' 'gettext')
optdepends=('lsof: device processes'
            'wget: plugin download'
            'gksu: perform as root functionality'
            'udevil: mount as non-root user and mount networks'
            'udisks: mount as non-root user'
            'udisks2: mount as non-root user')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
source=(https://github.com/IgnorantGuru/spacefm/archive/$pkgver.tar.gz
        libre.patch)
md5sums=('daeee7dcccea33d6258a0a9d783470c4'
         '30ba2b4b8f5ae7bf1552689b192eab89')

prepare() {
  # replace nonfree unrar with unar support
  cd $_pkgname-$pkgver
  patch -Np1 -i $srcdir/libre.patch src/ptk/ptk-file-archiver.c
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr \
    --disable-pixmaps
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}