# $Id: PKGBUILD 150046 2015-12-07 16:56:15Z allan $
# Maintainer (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): Mateusz Herych <heniekk@gmail.com>
# Contributor (Arch): Eric Belanger <eric@archlinux.org>
# Contributor (Arch): Darwin Bautista <djclue917@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=soundkonverter
pkgver=2.1.2
pkgrel=2.parabola1
pkgdesc="Front-end to various audio converters, without nonfree faac and mac recommendation"
arch=('i686' 'x86_64')
url="http://www.kde-apps.org/content/show.php?content=29024"
license=('GPL')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
depends=('kdebase-runtime' 'libkcddb' 'cdparanoia' 'taglib')
makedepends=('automoc4' 'cmake')
optdepends=('cdrkit: cdda2wav backend'
            'faad2: faad backend'
            'ffmpeg: ffmpeg backend'
            'flac: flac backend'
            'fluidsynth: flouidsynth backend'
            'lame: lame backend'
            'mplayer: mplayer backend'
            'mp3gain: mp3gain backend'
            'opus-tools: opus backend'
            'speex: speexenc, speexdec backends'
            'timidity++: midi backend'
            'twolame: twolame backend'
            'vorbisgain: vorbisgain backend'
            'vorbis-tools: vorbis tools backend'
            'wavpack: wavpack backend'
            'sox: sox plugin (change sample rate, various effects)')
install=$pkgname.install
source=("http://kde-apps.org/CONTENT/content-files/29024-${pkgname}-${pkgver}.tar.gz" soundkonverter-taglib-1.10.patch)
md5sums=('4f09193d6602de7952b985b9505731f8'
         '9e95e0a090028c8e585a2c96b8a80734')

prepare() {
  cd $pkgname-$pkgver
# Fix taglib 1.10 detection
  patch -p1 -i ../soundkonverter-taglib-1.10.patch
}

build() {
  cd "$srcdir"/$pkgname-$pkgver
  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}