# $Id: PKGBUILD 179682 2016-06-11 17:09:39Z arojas $
# Maintainer (Arch):
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=smplayer
pkgver=16.6.0
pkgrel=1.parabola1
pkgdesc="A complete front-end for MPlayer, without nonfree smtube recommendation"
arch=('i686' 'x86_64' 'armv7h')
url="http://smplayer.sourceforge.net/"
license=('GPL')
depends=('qt5-script' 'mplayer' 'hicolor-icon-theme')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'mpv: for using mpv instead of mplayer')
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
md5sums=('61d6fc855d13b33eccb3f5d2a1472220')

prepare() {
  cd $pkgname-$pkgver

  sed -i 's|DEFINES [+][=] YOUTUBE_SUPPORT|#DEFINES += YOUTUBE_SUPPORT|
          s|DEFINES [+][=] YT_USE_SCRIPT|#DEFINES += YT_USE_SCRIPT|
         ' src/smplayer.pro

  # fix GNU/Linux name
  sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
}

build() {
  cd $pkgname-$pkgver
  make PREFIX=/usr \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}

package() {
  cd $pkgname-$pkgver
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="$pkgdir" PREFIX="/usr" install
}