# $Id: PKGBUILD 244955 2015-08-28 08:42:55Z foutrelis $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Alessio 'mOLOk' Bolognino <themolok@gmail.com>
# Contributor (Arch): shamrok <szamrok@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=smplayer
pkgver=14.9.0.6994
pkgrel=1.parabola1
pkgdesc="A complete front-end for MPlayer, without nonfree smtube recommendation"
arch=('i686' 'x86_64')
url="http://smplayer.sourceforge.net/"
license=('GPL')
depends=('qt5-script' 'mplayer' 'hicolor-icon-theme' 'libxkbcommon-x11')
makedepends=('qt5-tools')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'mpv: for using mpv instead of mplayer')
install=smplayer.install
source=(https://downloads.sourceforge.net/project/$pkgname/Unstable/releases/$pkgname-$pkgver.tar.bz2
        add-missing-QDataStream-include.patch)
md5sums=('666a589b1fc3480a29e87f0ee7efd511'
         '418ab45eb94448fc8a2f44500c9742c2')

prepare() {
  cd "$pkgname-$pkgver"
  patch -Np1 -i ../add-missing-QDataStream-include.patch
  sed -i 's|DEFINES [+][=] YOUTUBE_SUPPORT|#DEFINES += YOUTUBE_SUPPORT|
          s|DEFINES [+][=] YT_USE_SCRIPT|#DEFINES += YT_USE_SCRIPT|
         ' src/smplayer.pro
}

build() {
  cd "$pkgname-$pkgver"
  make PREFIX=/usr \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}

package() {
  cd "$pkgname-$pkgver"
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="$pkgdir" PREFIX="/usr" install
}