# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer (arch): Josip Ponjavic <josipponjavic at gmail dot com>
# Contributor: Balló György <ballogyor+arch at gmail dot com>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
#  - build without qt5-webengine
#  - frozen at commit 79d6d67 - last commit with webkit support


pkgname=signon-ui
pkgver=0.17+20170320
pkgrel=1
pkgrel+=.parabola1
_commit=79d6d67
pkgdesc='UI component responsible for handling the user interactions which can happen during the login process of an online account'
arch=(x86_64)
arch+=(armv7h i686)
url="https://launchpad.net/online-accounts-signon-ui"
license=(GPL)
depends=(libaccounts-qt qt5-webkit signond libnotify)
source=("https://gitlab.com/accounts-sso/signon-ui/repository/archive.tar.gz?ref=$_commit")
sha256sums=('9b1005b51987703d0b2315bebfaa5acbd4f19fbb10dc215bb6dc8d035b5f91a6')


prepare() {
  cd signon-ui-*

  # Do not install tests
  sed -e 's|src \\|src|' -e '/tests/d' -i signon-ui.pro
}

build() {
  cd signon-ui-*

  qmake-qt5 PREFIX=/usr LIBDIR=/usr/lib
  make
}

package() {
  cd signon-ui-*

  make INSTALL_ROOT="$pkgdir" install
}