# $Id: PKGBUILD 135310 2011-08-12 14:45:48Z ibiru $
#mips64el Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
# Maintainer (Connochaetos): Henry Jensen <hjensen@connochaetos.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>
# Maintainer (Parabola): Márcio Silva <coadde@adinet.com.uy>

pkgname=sdl-libre
pkgver=1.2.15
pkgrel=1.1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard"
arch=('i686' 'x86_64')
url="http://www.libsdl.org"
license=('LGPL')
provides=("sdl=${pkgver}")
conflicts=('sdl')
depends=('glibc' 'libxext' 'libxrender' 'libx11')
makedepends=('alsa-lib' 'mesa' 'libpulse')
replaces=('sdl')
options=('!libtool')
source=(http://www.libsdl.org/release/SDL-${pkgver}.tar.gz
        sdl-1.2.14-fix-mouse-clicking.patch
        sdl-1.2.14-disable-mmx.patch
        riva_mmio.patch
        no-riva-accel.patch)
md5sums=('9d96df8417572a2afb781a7c4c811a85'
         '04d8c179f125e04bcd4c9d60e013c2d7'
         'e5c16b7611f62c7cb25f0534eff68852'
         'f5ab9ba6ba2bb8df74d0f768f9df3ea8'
         'eb2f5899db608ad27b379faa5e0beb80')

build() {
  cd ${srcdir}/SDL-${pkgver}
  patch -Np1 -i $srcdir/sdl-1.2.14-fix-mouse-clicking.patch
  patch -Np1 -i $srcdir/sdl-1.2.14-disable-mmx.patch
  patch -Np0 -i $srcdir/riva_mmio.patch
  patch -Np0 -i $srcdir/no-riva-accel.patch
  ./configure --prefix=/usr --disable-nasm --enable-alsa --enable-esd \
              --with-x --disable-rpath --disable-static
  make
}

package() {
  cd ${srcdir}/SDL-${pkgver}
  make DESTDIR=${pkgdir} install
}