# Maintainer (Arch): Thomas Dziedzic <gostrc@gmail.com>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): John Proctor <jproctor@prium.net>
# Contributor (Arch): Jeramy Rutley <jrutley@gmail.com>
# Maintainer: Daniel Milewski <niitotantei@riseup.net>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=(ruby ruby-docs)
pkgver=2.2.1
_jsonver=1.8.1
pkgrel=1.parabola1
arch=(i686 x86_64)
url='http://www.ruby-lang.org/en/'
license=(BSD custom)
makedepends=(gdbm openssl libffi doxygen graphviz libyaml ttf-dejavu tk)
options=(!emptydirs)
mksource=(http://cache.ruby-lang.org/pub/ruby/${pkgver:0:3}/ruby-${pkgver}.tar.xz
          https://github.com/flori/json/archive/v${_jsonver}.tar.gz
          json-${_jsonver}.gem
          libre.patch)
source=(https://repo.parabola.nu/other/ruby-libre/ruby-libre-${pkgver}.tar.xz
        gemrc)
mksha1sums=('31bbdb17237863bd26b3aa32c613fe42c95ccd60'
            '043ed2df4b0ce2174c9c020ffcb4ec31f9fde560'
            '2cd288d00c5211e4c9d9338080b30af65cbb143a'
            '66e71a368eb174976fd23af9f9bca4faa4462273')
sha1sums=('8a47cbc1a07270c1c7c7edd612da466bd1dcab59'
          'de4b760b7e2cd9af88ca67536ce37b950f1ee514')

mksource() {
  rm -rv ruby-${pkgver}/ext/json
  rm -rv ruby-${pkgver}/test/json

  rm -rv json-${_jsonver}/ext

  cp -v json-${_jsonver}.gem ruby-${pkgver}/gems

  patch -Np0 -i libre.patch
}

build() {
  cd ruby-${pkgver}

  PKG_CONFIG=/usr/bin/pkg-config ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --sharedstatedir=/var/lib \
    --libexecdir=/usr/lib/ruby \
    --enable-shared \
    --disable-rpath \
    --with-dbm-type=gdbm_compat

  make
}

check() {
  cd ruby-${pkgver}

  make test
}

package_ruby() {
  pkgdesc='An object-oriented language for quick and easy programming, with free variant of json gem'
  depends=(gdbm openssl libffi libyaml gmp zlib)
  optdepends=(
      'ruby-docs: Ruby documentation'
      'tk: for Ruby/TK'
  )
  provides=(rubygems rake)
  conflicts=(rake)
  backup=(etc/gemrc)
  install=ruby.install

  cd ruby-${pkgver}

  make DESTDIR="${pkgdir}" install-nodoc

  install -D -m644 ${srcdir}/gemrc "${pkgdir}/etc/gemrc"

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/ruby/LICENSE"
  install -D -m644 BSDL "${pkgdir}/usr/share/licenses/ruby/BSDL"
}

package_ruby-docs() {
  pkgdesc='Documentation files for ruby'

  cd ruby-${pkgver}

  make DESTDIR="${pkgdir}" install-doc install-capi

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/ruby-docs/LICENSE"
  install -D -m644 BSDL "${pkgdir}/usr/share/licenses/ruby-docs/BSDL"
}