# $Id: PKGBUILD 220603 2014-08-23 13:00:49Z heftig $
# Maintainer (Arch): Daniel Isenmann <daniel@archlinux.org>
# Contributor (Arch): orelien <aurelien.foret@wanadoo.fr>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=rp-pppoe
pkgver=3.11
pkgrel=7.parabola1
pkgdesc="Roaring Penguin's Point-to-Point Protocol over Ethernet client, without nonfree ServPoET recommendation"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.roaringpenguin.com/pppoe/"
license=('GPL')
depends=('ppp=2.4.7' 'sh' 'net-tools')
backup=(etc/ppp/pppoe.conf etc/ppp/firewall-standalone etc/ppp/firewall-masq 
        etc/ppp/pppoe-server-options)
options=('!makeflags')
replaces=('rp-pppoe-libre')
conflicts=('rp-pppoe-libre')
install=rp-pppoe.install
source=(http://www.roaringpenguin.com/files/download/rp-pppoe-$pkgver.tar.gz{,.sig} 
       adsl.service 
       kmode.patch
       libre.patch)

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  
  ## Adding patch to remove nonfree software recommendation (ServPoET)
  patch -Np1 -i "$srcdir/libre.patch"

  cd "$srcdir/$pkgname-$pkgver/src"
  patch -Np2 -i ../../kmode.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver/src"
  ./configure --prefix=/usr --sbindir=/usr/bin --enable-plugin
  make PLUGIN_DIR="/usr/lib/rp-pppoe" all rp-pppoe.so
}

package() {
  cd "$srcdir/$pkgname-$pkgver/src"
  make PLUGIN_DIR="/usr/lib/rp-pppoe" DESTDIR="$pkgdir" install

  #install -Dm755 "$srcdir/adsl" "$pkgdir/etc/rc.d/adsl"
  install -Dm644 "$srcdir/adsl.service" "$pkgdir/usr/lib/systemd/system/adsl.service"
}
md5sums=('13b5900c56bd602df6cc526e5e520722'
         'SKIP'
         '926b00aa2a0c0d3a21970acde9695e47'
         'd38a903a247d689ff0323d7b6caa1c6b'
         '3c53d550ac408608abb0b6cd6b76b6c2')