# $Id: PKGBUILD 257681 2016-01-09 09:49:01Z arojas $
# Maintainer (Arch): Daniel Isenmann <daniel@archlinux.org>
# Contributor (Arch): orelien <aurelien.foret@wanadoo.fr>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=rp-pppoe
pkgver=3.12
pkgrel=3.parabola1
pkgdesc="Roaring Penguin's Point-to-Point Protocol over Ethernet client, without nonfree ServPoET recommendation"
arch=('i686' 'x86_64' 'armv7h')
url="https://www.roaringpenguin.com/products/pppoe"
license=('GPL')
depends=('ppp=2.4.7' 'sh' 'net-tools')
backup=(etc/ppp/pppoe.conf etc/ppp/firewall-standalone etc/ppp/firewall-masq 
        etc/ppp/pppoe-server-options)
options=('!makeflags')
replaces=('rp-pppoe-libre')
conflicts=('rp-pppoe-libre')
install=rp-pppoe.install
source=(http://www.roaringpenguin.com/files/download/rp-pppoe-$pkgver.tar.gz{,.sig} 
       adsl.service 
       kmode.patch
       rp-pppoe-linux-headers.patch
       libre.patch)
validpgpkeys=('FC2E9B645468698FD7B21655C1842E2A126F42E0') # Dianne Skoll

prepare() {
  cd $pkgname-$pkgver
  
  ## remove nonfree software recommendation (ServPoET)
  rm -v SERVPOET
  patch -Np1 -i ../libre.patch

  patch -Np1 -i ../kmode.patch
  patch -Np1 -i ../rp-pppoe-linux-headers.patch
}

build() {
  cd $pkgname-$pkgver/src
  ./configure --prefix=/usr --sbindir=/usr/bin --enable-plugin
  make PLUGIN_DIR="/usr/lib/rp-pppoe" all rp-pppoe.so
}

package() {
  cd $pkgname-$pkgver/src
  make PLUGIN_DIR="/usr/lib/rp-pppoe" DESTDIR="$pkgdir" install

  #install -Dm755 "$srcdir/adsl" "$pkgdir/etc/rc.d/adsl"
  install -Dm644 "$srcdir/adsl.service" "$pkgdir/usr/lib/systemd/system/adsl.service"
}
sha256sums=('00794e04031546b0e9b8cf286f2a6d1ccfc4a621b2a3abb2d7ef2a7ab7cc86c2'
            'SKIP'
            '6593ca054834a6d3bc046456b127ba3652b6203e287ef0f6a57f8db27059f6d2'
            'c690186ba48a3ee78b87e655801a8ac5bb1b21a67ded9aa7942eb3514e98505f'
            '99761e5f84535d02e2004000567cab009ef49ed96f0534a5937e63d15dbed184'
            'd3810c2c8d6f4b606a073922a6afdf0eb6e38441de68e918f198afa6e020150e')