# $Id$
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor (Arch): Themaister <maister@archlinux.us>
# Contributor (Arch): lifning <definelightning@gmail.com>

pkgname=retroarch
pkgver=1.7.0
pkgrel=2.parabola1
pkgdesc='Reference frontend for the libretro API, without nonfree software support, libretro-genesis-plus and libretro-snes9x recommendation'
arch=('x86_64' 'i686' 'armv7h')
url='http://www.libretro.com/'
license=('GPL')
groups=('libretro')
depends=('alsa-lib' 'gcc-libs' 'glibc' 'libdrm' 'libgl' 'libpulse' 'libusb'
         'libx11' 'libxcb' 'libxext' 'libxinerama' 'libxkbcommon' 'libxv'
         'libxxf86vm' 'mesa' 'openal' 'sdl2' 'wayland' 'zlib'
         'libass.so' 'libavcodec.so' 'libavformat.so' 'libavutil.so'
         'libfreetype.so' 'libswresample.so' 'libswscale.so' 'libudev.so')
makedepends=('vulkan-icd-loader')
optdepends=('libretro-overlays: Collection of overlays'
            'libretro-shaders: Collection of shaders'
            'python: retroarch-cg2glsl'
            'retroarch-assets-xmb: XMB menu assets'
            'retroarch-autoconfig-udev: udev joypad autoconfig')
backup=('etc/retroarch.cfg')
source=("retroarch-${pkgver}.tar.gz::https://github.com/libretro/RetroArch/archive/v${pkgver}.tar.gz"
        'retroarch-config.patch'
        'libre.patch')
sha256sums=('b32fa4a37ff777e9fe45eeef7ccf2e4e06520dd268584034f687a494dc9f5af1'
            '8dca43954d05ea1f989932fb26828b6e8325394eec070c4530dd21eab3f02c44'
            '4877a7eb4b848f05db49e8c4a14a563a353aa42679faac94d891ff6351949aa7')

prepare() {
  cd RetroArch-${pkgver}

  patch -Np0 -i ../retroarch-config.patch
  patch -Np1 -i ${srcdir}/libre.patch
}

build() {
  cd RetroArch-${pkgver}

  ./configure \
    --prefix='/usr' \
    --disable-cg \
    --disable-jack \
    --disable-oss \
    --disable-sdl
  make
  make -C libretro-common/audio/dsp_filters
  make -C gfx/video_filters
}

package() {
  cd RetroArch-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -Dm 644 libretro-common/audio/dsp_filters/*.{dsp,so} -t "${pkgdir}"/usr/lib/retroarch/filters/audio/
  install -Dm 644 gfx/video_filters/*.{filt,so} -t "${pkgdir}"/usr/lib/retroarch/filters/video/
}

# vim: ts=2 sw=2 et: