#Maintainer (Arch): Xyne <ac xunilhcra enyx, backwards>
#Maintainer: André Silva <emulatorman@parabola.nu>
_pkgname=reflector
pkgname=reflector-parabola
pkgver=2014.8
pkgrel=1
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list (Parabola rebranded)'
arch=(any)
license=(GPL)
url="http://xyne.archlinux.ca/projects/reflector"
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
source=(
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2014.8.tar.xz
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2014.8.tar.xz.sig
  rebranding.patch
)
sha512sums=(
  c548a5fe638c465803ff7962bdebeef3740b0cbfc65ba5fbbfb1b07d485e90ee1ea35c71e07f9ac3cb9964cf754b28edd81b3df2f3a14c7686ca7fb84cc471eb
  e9177dcc04b498ffaeadfd83278b0f51dfd7167267e6556ca55768afbe01b1d712ade2ab7252a191002d12da07e5330ade410d8dfa99112ec2aaa93b24d46beb
  fc042cd3ffa67445a874d460659e43a55607271a2b776a4c810507443babe3a505014a2c48e0e4760cb7c19d6d66797e09c6b1b200985f4685eb8ed5c2347819
)
md5sums=(
  b7bf2653b68e79ee40fc715bf180490e
  583a9a95465c5daa6c0ca6bb86e96f0d
  d938639a354d46e9819f1f36b3aa5fb3
)

prepare ()
{
  cd "$srcdir/$_pkgname-$pkgver"
  # Rebranding for Parabola
  patch -Np1 -i "$srcdir/rebranding.patch"
}

package ()
{
  cd "$srcdir/$_pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm755 "$srcdir/$_pkgname-$pkgver/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
}


# vim: set ts=2 sw=2 et: