# $Id: PKGBUILD 291844 2017-03-30 10:00:44Z arojas $
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Contributor (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): Dan Vratil <progdan@progdansoft.com>
# Contributor (Arch): thotypous <matiasΘarchlinux-br·org>
# Contributor (Arch): delor <bartekpiech gmail com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=qtcreator
pkgver=4.2.1
_pkgver=v4.2.1
pkgrel=4.parabola1
pkgdesc='Lightweight, cross-platform integrated development environment, without nonfree qt5-webengine support'
arch=('i686' 'x86_64' 'armv7h')
url='http://qt-project.org'
license=('LGPL')
depends=('qt5-tools' 'qt5-declarative' 'qt5-script' 'qt5-quickcontrols' 'qt5-quickcontrols2' 'clang' 'qbs')
makedepends=('git' 'mesa' 'llvm')
options=('docs')
optdepends=('qt5-doc: integrated Qt documentation'
            'qt5-examples: welcome page examples'
            'qt5-translations: for other languages'
            'gdb: debugger'
            'cmake: cmake project support'
            'x11-ssh-askpass: ssh support'
            'git: git support'
            'mercurial: mercurial support'
            'bzr: bazaar support'
            'valgrind: analyze support')
source=("http://download.qt.io/official_releases/qtcreator/4.2/${pkgver}/qt-creator-opensource-src-${pkgver}.tar.xz"
        'libre.patch'
        '0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch')
sha512sums=('3135b64a36240bffe41c1373d5e5d5327cfa556f42eb339afcacf2f8d294843b96269269417ab262ba8292e28a57472c78ab7ff4686f0360616a4014c75809e9'
            '57dd505e183661463567b6a7711a7b58f1d5e5b6ecc808acbae4df78366ed3d08be9eb04f6883ad8fd15318c826645e655e7028136b16a801e0084d3a2b51b2a'
            'af0a0d5a2fadcfce14def65be73c99bff8227794b9ad2be333713c89e226e2c6b43802a802b6e30f3e6c1b4b77f31183bffdcca3404d9686f15fa84dfc64d1a1')

prepare() {
  cd  $srcdir/qt-creator-opensource-src-$pkgver
  patch -p1 -i ../libre.patch
  rm -rv src/plugins/help/webenginehelpviewer.{cpp,h}

  if [[ "$CARCH" =~ ^arm*|^aarch64$ ]]; then
    git apply ../0001-Fix-Allow-qt-creator-to-build-on-arm-aarch32-and-aar.patch
  fi
}

build() {
  [[ -d build ]] && rm -r build
  mkdir build && cd build

  LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr qmake QMAKE_CFLAGS_ISYSTEM=-I \
    CONFIG+=journald -r ../qt-creator-opensource-src-${pkgver}/qtcreator.pro
  make
  make docs -j1
}

package() {
  cd build

  make INSTALL_ROOT="${pkgdir}/usr/" install
  make INSTALL_ROOT="${pkgdir}/usr/" install_docs

  install -Dm644 ${srcdir}/qt-creator-opensource-src-${pkgver}/LICENSE.GPL3-EXCEPT ${pkgdir}/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
}