# $Id: PKGBUILD 216383 2014-07-03 06:24:56Z fyan $
# Maintainer (Arch): Ronald van Haren <ronald.archlinux.org>
# Contributor (Arch): eric <eric@archlinux.org>
# Contributor (Arch): Tom Newsom <Jeepster@gmx.co.uk>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: xihh <hahj87@gmail.com>

_pkgname=psutils-libre
pkgname=psutils
pkgver=1.17
pkgrel=6.parabola1
arch=('i686' 'x86_64' 'armv7h')
pkgdesc="A set of postscript utilities, without nonfree files"
url="http://knackered.org/angus/psutils/"
license=('custom')
depends=('glibc' 'ghostscript')
provides=('psutils-lprng')
replaces=('psutils-lprng' 'psutils-libre')
conflicts=('psutils-lprng' 'psutils-libre')
options=('!makeflags')
mksource=("https://sources.archlinux.org/other/psutils/${pkgname}-${pkgver}.tar.gz"
          'libre.patch')
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
        'psutils-1.17.diff')
mksha512sums=('91feff88c885173ab1c4ba6b5ffd0d9e90bfa6105479b074065584fc2a87e78fbe71e4bc90d2e7079d86b467caf092b6744b0ea4234880ba78cad8dd7820de77'
              '795f45c6315e3c02485d1d5243c1541992b669539257249a185f57136e623c489a9f3635d3f171f698428aeb9710332cf36bb0aa0ade8ea351514044630f12f0')
sha512sums=('d55838fc3a736f2b981fdd748a6e531066ed4ef8775636a7692b1129c0dd176243a0cf3e64917ec745f0121173c26e3a02fba2dcb244dc4dca79f06f3d13b913'
            '795f45c6315e3c02485d1d5243c1541992b669539257249a185f57136e623c489a9f3635d3f171f698428aeb9710332cf36bb0aa0ade8ea351514044630f12f0')

mksource() {
  cd "${srcdir}/${pkgname}"
  # apply patch to remove nonfree files support from Makefile
  patch -Np1 -i "${srcdir}/libre.patch"
  # remove nonfree files
  rm -v {fixmacps.{man,pl},md{68_0,71_0}.ps} 
}

build() {
  cd "${srcdir}/${pkgname}"
  patch -Np1 -i "${srcdir}/psutils-1.17.diff"
  make -f Makefile.unix BINDIR=/usr/bin \
    INCLUDEDIR=/usr/include/psutils PERL=/usr/bin/perl \
    MANDIR=/usr/share/man/man1 \
    CFLAGS="$CFLAGS -DPAPER=\\\"letter\\\" -DUNIX -Wall" \
    CCFLAGS="$LDFLAGS"
}

package() {
  cd "${srcdir}/${pkgname}"
  install -d -m755 "${pkgdir}/usr/include"
  install -d -m755 "${pkgdir}/usr/share/man"
  make -f Makefile.unix BINDIR="${pkgdir}/usr/bin" \
    INCLUDEDIR="${pkgdir}/usr/include/psutils" PERL=/usr/bin/perl \
    MANDIR="${pkgdir}/usr/share/man/man1" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/"
}