# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of pcre

_pkgname=pcre
pkgname=pcre-static
pkgver=8.38
pkgrel=3
pkgdesc='A library that implements Perl 5-style regular expressions (static libraries only)'
arch=('i686' 'x86_64' 'armv7h')
url='http://www.pcre.org/'
license=('BSD')
depends=('gcc-libs-static' 'readline-static' 'bzip2-static' 'pcre')
options=('staticlibs')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8') # Philip Hazel
source=("ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/$_pkgname-$pkgver.tar.bz2"{,.sig}
        '01-CVE-2016-1283.patch')
md5sums=('00aabbfe56d5a48b270f999b508c5ad2'
         'SKIP'
         '722aba6455a3f0240eaa22289f0176a0')

prepare() {
  cd $_pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local filename
  for filename in "${source[@]}"; do
    if [[ "$filename" =~ \.patch$ ]]; then
      msg2 "Applying patch $filename"
      patch -p1 -N -i "$srcdir/$filename"
    fi
  done
  :
}

build() {
  cd $_pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-unicode-properties \
    --enable-pcre16 \
    --enable-pcre32 \
    --enable-jit \
    --enable-pcregrep-libz \
    --enable-pcregrep-libbz2 \
    --enable-pcretest-libreadline
  make
}

check() {
  cd $_pkgname-$pkgver
  make -j1 check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{bin,include,lib/pkgconfig,share}
  rm -v ${pkgdir}/usr/lib/lib*.so*
}

# vim:set ts=2 sw=2 et: