# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=(parabolaweb-utils parabolaweb-dev)
pkgver=20150417
pkgdesc="Utilities for managing the ParabolaWeb website application"
url="https://projects.parabola.nu/packages/parabolaweb-utils.git/"
license=('GPL2')

# The commit to get dependency info for
# Bump pkgrel instead of pkgver if updating this is the only change
_parabolaweb_commit=d2eb47c0dfc068c7727232d89daeee377969288d

pkgrel=1
epoch=1
arch=('i686' 'x86_64')

source=("https://projects.parabolagnulinux.org/packages/$pkgname.git/snapshot/$pkgname-$pkgver.tar.bz2"
	"requirements_prod-${_parabolaweb_commit}.txt::https://projects.parabolagnulinux.org/parabolaweb.git/plain/requirements_prod.txt?id=${_parabolaweb_commit}")
md5sums=('12419393e81d9a890a98a676eec4103e'
         '28653bf82e9c73b6f1d736bf107d2a40')

build() {
	cd "$srcdir/$pkgname-$pkgver"
	prod_file="file://${srcdir}/requirements_prod-${_parabolaweb_commit}.txt" make
}

package_parabolaweb-utils() {
	cd "$srcdir/$pkgbase-$pkgver"
	depends=($(< depends.txt))
	backup=('etc/conf.d/parabolaweb')
	make install DESTDIR="$pkgdir"
}

package_parabolaweb-dev() {
	cd "$srcdir/$pkgbase-$pkgver"
	pkgdesc="Depends on packages needed to develop ParabolaWeb"
	depends=($(sed -r -e 's/\s*#.*//' depends_make.txt))
}